Лекция №4.1: Сортировки массивов

страницы: 1 2

Простые и улучшенные методы упорядочения данных.

Содержание

Содержание
Задача сортировки
Простые сортировки
Примечания

Задача сортировки

Эта лекция посвящена сугубо алгоритмической проблеме упорядочения данных.

Необходимость отсортировать какие–либо величины возникает в программировании очень часто. К примеру, входные данные подаются «вперемешку», а вашей программе удобнее обрабатывать упорядоченную последовательность. Существуют ситуации, когда предварительная сортировка данных позволяет сократить содержательную часть алгоритма в разы, а время его работы — в десятки раз.

Однако верно и обратное. Сколь бы хорошим и эффективным ни был выбранный вами алгоритм, но если в качестве подзадачи он использует «плохую» сортировку, то вся работа по его оптимизации оказывается бесполезной. Неудачно реализованная сортировка входных данных способна заметно понизить эффективность алгоритма в целом.

Методы упорядочения подразделяются на внутренние (обрабатывающие массивы) и внешние (занимающиеся только файлами)¹.

Эту лекцию мы посвятим только внутренним сортировкам. Их важная особенность состоит в том, что эти алгоритмы не требуют дополнительной памяти: вся работа по упорядочению производится внутри одного и того же массива.

Простые сортировки

К простым внутренним сортировкам относят методы, сложность которых пропорциональна квадрату размерности входных данных. Иными словами, при сортировке массива, состоящего из N компонент, такие алгоритмы будут выполнять С*N² действий, где С — некоторая константа.

Количество действий, необходимых для упорядочения некоторой последовательности данных, конечно же, зависит не только от длины этой последовательности, но и от её структуры. Например, если на вход подаётся уже упорядоченная последовательность (о чём программа, понятно, не знает), то количество действий будет значительно меньше, чем в случае перемешанных входных данных.

Как правило, сложность алгоритмов подсчитывают раздельно по количеству сравнений и по количеству перемещений данных в памяти (пересылок), поскольку выполнение этих операций занимает различное время. Однако точные значения удаётся найти редко, поэтому для оценки алгоритмов ограничиваются лишь понятием «пропорционально», которое не учитывает конкретные значения констант, входящих в итоговую формулу. Общую же эффективность алгоритма обычно оценивают «в среднем»: как среднее арифметическое от сложности алгоритма «в лучшем случае» и «в худшем случае», то есть (Eff_best + Eff_worst) / 2.

Сортировка простыми вставками

Самый простой способ сортировки², который приходит в голову, — это упорядочение данных по мере их поступления. В этом случае при вводе каждого нового значения можно опираться на тот факт, что все предыдущие элементы уже образуют отсортированную последовательность.

Алгоритм ПрВст

Первый элемент записать «не раздумывая».
Пока не закончится последовательность вводимых данных, для каждого нового её элемента выполнять следующие действия:
— начав с конца уже существующей упорядоченной последовательности, все её элементы, которые больше, чем вновь вводимый элемент, сдвинуть на 1 шаг назад;
— записать новый элемент на освободившееся место.

При этом, разумеется, можно прочитать все вводимые элементы одновременно, записать их в массив, а потом «воображать», что каждый очередной элемент был введён только что. На суть и структуру алгоритма это не повлияет.

Реализация алгоритма ПрВст

for i := 2 to N do
if a[i - 1] > a[i] then                {*}
begin
    x := a[i];
    j := i - 1;
   while (j > 0) and (a[j] > x) do      {**}
   begin
      a[j + 1] := a[j];
      j := j - 1;
   end;
    a[j + 1] := x;
end;

Метод прямых вставок с барьером (ПрВстБар)

Для того, чтобы сократить количество сравнений, производимых нашей программой, дополним сортируемый массив нулевой компонентой (это следует сделать в разделе описаний var) и будем записывать в неё поочерёдно каждый вставляемый элемент (сравните строки {*} и {**} в приведённых вариантах программы). В тех случаях, когда вставляемое значение окажется меньше, чем a[1], компонента a[0] будет работать как «барьер», не дающий индексу j выйти за нижнюю границу массива. Кроме того, компонента a[0] может заменить собою и дополнительную переменную х:

for i := 2 to N do
if a[i - 1] > a[i] then
begin
    a[0] := a[i];             {*}
    j := i - 1;
   while a[j] > a[0] do      {**}
   begin
      a[j + 1] := a[j];
      j := j - 1;
   end;
    a[j + 1] := a[0];
end;

Эффективность алгоритма ПрВстБар

Понятно, что для этой сортировки наилучшим будет случай, когда на вход подаётся уже упорядоченная последовательность данных. Тогда алгоритм ПрВстБар совершит N-1 сравнение и 0 пересылок данных.

В худшем же случае — когда входная последовательность упорядочена «наоборот» — сравнений будет уже (N + 1) * N / 2, а пересылок (N - 1) * (N + 3). Таким образом, этот алгоритм имеет сложность ~N² (читается «порядка эн квадрат») по обоим параметрам.

Пример сортировки

Предположим, что нужно отсортировать следующий набор чисел:

5 3 4 3 6 2 1

Выполняя алгоритм ПрВстБар, мы получим такие результаты (подчёркнута уже отсортированная часть массива, полужирным выделена сдвигаемая последовательность, а квадратиком выделен вставляемый элемент):

         Состояние массива      Сдвиги  Сравнения  Пересылки данных

0 шаг:      5343621
1 шаг:      5343621                1     1+1³        1+2⁴
2 шаг:      3543621                1     1+1         1+2
3 шаг:      3453621                2     2+1         2+2
4 шаг:      3345621                0      1           0
5 шаг:      3345621                5     5+1         5+2
6 шаг:      2334561                6     6+1         6+2
Результат: 1233456               15      20          25

Сортировка бинарными вставками

Сортировку простыми вставками можно немного улучшить: поиск «подходящего места» в упорядоченной последовательности можно вести более экономичным способом, который называется Двоичный поиск в упорядоченной последовательности. Он напоминает детскую игру «больше–меньше»: после каждого сравнения обрабатываемая последовательность сокращается в два раза.

Пусть, к примеру, нужно найти место для элемента 7 в таком массиве:

[2 4 6 8 10 12 14 16 18]

Найдём средний элемент этой последовательности (10) и сравним с ним семёрку. После этого всё, что больше 10 (да и саму десятку тоже), можно смело исключить из дальнейшего рассмотрения:

[2 4 6 8]10 12 14 16 18

Снова возьмём середину в отмеченном куске последовательности, чтобы сравнить её с семеркой. Однако здесь нас поджидает небольшая проблема: точной середины у новой последовательности нет, поэтому нужно решить, который из двух центральных элементов станет этой «серединой». От того, к какому краю будет смещаться выбор в таких «симметричных» случаях, зависит окончательная реализация нашего алгоритма. Давайте договоримся, что новой «серединой» последовательности всегда будет становиться левый центральный элемент. Это соответствует вычислению номера «середины» по формуле

nomer_sred := (nomer_lev + nomer_prav) div 2

Итак, отсечём половину последовательности:

2 4[6  8]10 12 14 16 18

И снова:

2 4 6 [8]10 12 14 16 18
2 4 6][8 10 12 14 16 18

Таким образом, мы нашли в исходной последовательности место, «подходящее» для нового элемента. Если бы в той же самой последовательности нужно было найти позицию не для семёрки, а для девятки, то последовательность границ рассматриваемых промежутков была бы такой:

[2 4 6 8] 10 12 14 16 18
 2 4[6 8] 10 12 14 16 18
 2 4 6[8] 10 12 14 16 18
 2 4 6 8][10 12 14 16 18

Из приведенных примеров уже видно, что поиск ведётся до тех пор, пока левая граница не окажется правее(!) правой границы. Кроме того, по завершении этого поиска последней левой границей окажется как раз тот элемент, на котором необходимо закончить сдвиг «хвоста» последовательности.

Будет ли такой алгоритм универсальным? Давайте проверим, что же произойдёт, если мы станем искать позицию не для семёрки или девятки, а для единицы:

 [2 4 6 8]10 12 14 16 18
 [2]4 6 8 10 12 14 16 18
][2 4 6 8 10 12 14 16 18

Как видим, правая граница становится неопределённой — выходит за пределы массива. Будет ли этот факт иметь какие–либо неприятные последствия? Очевидно, нет, поскольку нас интересует не правая, а левая граница.

«А что будет, если мы захотим добавить 21?» — спросит особо въедливый читатель. Проверим это:

2 4 6 8 10[12 14 16 18]
2 4 6 8 10 12 14[16 18]
2 4 6 8 10 12 14 16[18]
2 4 6 8 10 12 14 16 18][

Кажется, будто всё плохо: левая граница вышла за пределы массива; непонятно, что нужно сдвигать...

Вспомним, однако, что в реальности на (N + 1)–й позиции как раз и находится вставляемый элемент (21). Таким образом, если левая граница вышла за рассматриваемый диапазон, получается, что ничего сдвигать не нужно. Вообще же, такие действия выглядят явно лишними, поэтому от них стоит застраховаться, введя одну дополнительную проверку в текст алгоритма.

Реализация алгоритма БинВст

for i := 2 to n do
if a[i - 1] > a[i] then
begin
    x := a[i];
    left := 1;
    right := i - 1;
   repeat
      sred := (left + right) div 2;
     if a[sred] < x then
        left := sred + 1
     else right := sred - 1;
   until left > right;
   for j := i - 1 downto left do
      a[j + 1] := a[j];
    a[left] := x;
end;

Эффективность алгоритма БинВст

Теперь на каждом шаге выполняется не N, а log N проверок⁵, что уже значительно лучше (для примера, сравните 1000 и 10 = log 1024). Следовательно, всего будет совершено N*log N сравнений. Впрочем, улучшение это не слишком значительное, ведь по количеству пересылок наш алгоритм по–прежнему имеет сложность «порядка N²».

Сортировка простым выбором

Попробуем теперь сократить количество пересылок элементов.

Алгоритм ПрВыб

На каждом шаге (всего их будет ровно N - 1) будем производить такие действия:

найдём минимум среди всех ещё не упорядоченных элементов;
поменяем его местами с первым «по очереди» не отсортированным элементом. Мы надеемся, что читателям очевидно, почему к концу работы этого алгоритма последний (N–й) элемент массива автоматически окажется максимальным.

Реализация ПрВыб

for i := 1 to n - 1 do
begin
  min_ind := i;
for j := i + 1 to n do
   if a[j] <= a[min_ind] then {***}
      min_ind:= j;
if min_ind <> i then
begin
    x := a[i];
    a[i] := a[min_ind];
    a[min_ind] := x;
end;
end;

Эффективность алгоритма ПрВыб

В лучшем случае (если исходная последовательность уже упорядочена), алгоритм ПрВыб произведёт (N - 1) * (N + 2) / 2 сравнений и 0 пересылок данных. В остальных же случаях количество сравнений останется прежним, а вот количество пересылок элементов массива будет равным 3 * (N - 1).

Таким образом, алгоритм ПрВыб имеет квадратичную сложность (~N²) по сравнениям и линейную (~N) — по пересылкам.

Замечание. Если перед вами поставлена задача отсортировать строки двумерного массива (размерности NxN) по значениям его первого столбца, то сложность алгоритма ПрВыб, модифицированного для решения этой задачи, будет квадратичной (N² сравнений и N² пересылок), а алгоритма БинВст — кубической (N*log N сравнений и N³ пересылок). Комментарии, как говорится, излишни.

Пример сортировки

Предположим, что нужно отсортировать тот же набор чисел, при помощи которого мы иллюстрировали метод сортировки простыми вставками:

5 3 4 3 6 2 1

Теперь мы будем придерживаться алгоритма ПрВыб (подчёркнута несортированная часть массива, а квадратиком выделен её минимальный элемент):

1 шаг:        5343621
2 шаг:        1343625
3 шаг:        1243635        {***}⁶
4 шаг:        1233645{ничего не делаем}
5 шаг:        1233645
6 шаг:        1233465
результат:    1233456

Сортировка простыми обменами

Рассмотренными сортировками, конечно же, не исчерпываются все возможные методы упорядочения массивов.

Существуют, например, алгоритмы, основанные на обмене двух соседних элементов: Пузырьковая и Шейкерная сортировки. Обе имеют сложность порядка N², однако и по скорости работы на любых входных данных, и по простоте реализации они проигрывают другим простым сортировкам. Поэтому мы настойчиво советуем читателю не прельщаться красивыми названиями, за которыми не стоит никакой особенной выгоды.

Тем же, кто всё-таки желает ознакомиться с обменными сортировками, а также с подробными данными по сравнению различных сортировок, мы рекомендуем труды Д. Кнута⁷ или Н. Вирта⁸.

страницы: 1 2

Дальше »»»

Примечания

^ Более подробную информацию о различных алгоритмах упорядочения смотрите в книге Дональда Кнута «Искусство программирования ЭВМ», том 3: «Сортировка и поиск».
^ В названиях алгоритмов мы будем следовать Кнуту.
^ Одно — при сдвиге, и ещё одно — при проверке необходимости сдвига
^ Одно — при сдвиге, и ещё две — при переписывании вставляемого элемента.
^ Напомним, что log N означает log₂ N
^ Если бы в строке {***} программы ПРВыб стоял знак строгого неравенства, то в качестве минимума была бы выбрана первая тройка. Однако очевидно, что выгоднее брать последний из совпадающих элементов: благодаря этому все они оказываются левее, чем тот превосходящий всех их элемент, с которым выбранный минимум меняется местами.
^ Д. Кнут. Искусство программирования для ЭВМ. Т.3. Сортировка и поиск (любое издание).
^ Н. Вирт. Алгоритмы и структуры данных (любое издание).